(requires '', "")
(make sure you exit the code editor with '@' first)
Making Mobile Programs |
MANUAL FOR MOBPROGS ON ANSALON and ROM 2.4 FROMAnsalon
http://www.ansalonmud.com http://ansalon.wolfpaw.net telnet://ansalonmud.com:8679 telnet://ansalon.wolfpaw.net:8679 telnet://204.209.44.23:8679 Version 2.3.4 September 28 2008 The object of this document is to help you avoid some of the pitfalls that many beginning mprog'ers make, myself heavily included. It exists to be a definitive guide to making mobile programs. - Skol
| CODE EDITOR | |
| |
| .r 'old' 'new' | - replace a substring (requires '', "") |
| .r OLD NEW | - Swap a word for a new one |
| .h | - get help (this info) |
| .s | - show string so far |
| .f | - Format (word wrap) string |
| .c | - clear string so far |
| .ld # | - delete line number # |
| .li # (str) | - insert (str) at line # |
| .lr # (str) | - replace line # with (str) |
| @ | - end string |
| done | - exits editor (make sure you exit the code editor with '@' first) |
| VARIABLE | MOBILE | ACTOR | VICTIM | RANDOM | OBJECT | 2ND_OBJECT |
| ||||||
| name | $i | $n | $t | $r | $o | $p |
| shrt_desc/title | $I | $N | $T | $R | $O | $P |
| he/she/it | $j | $e | $E | $J | -- | -- |
| him/her/it | $l | $m | $M | $L | -- | -- |
| his/hers/its | $k | $s | $S | $K | -- | -- |
| a/an | -- | -- | -- | -- | $a | $A |
| VARIABLE | Explanation |
|
| |
| $i | - the first of the names of the mobile itself. |
| $I | - the short description of the mobile itself. |
| $n | - the name of whomever caused the trigger to happen. |
| $N | - the name and title of whomever caused the trigger to happen. |
| $t | - the name of a secondary character target (i.e A smiles at B) |
| $T | - the short description, or name and title of target (NPC vs PC) |
| $r | - the name of a random PC in the room with the mobile |
| $R | - the short description, or name and title of the random PC |
| $q | - the name of the MOB PROGRAM target (see MOB REMEMBER) |
| $Q | - the short description of the MOB PROGRAM target |
| $j | - he,she,it based on sex of $i. |
| $e | - he,she,it based on sex of $n. |
| $E | - he,she,it based on sex of $t. |
| $J | - he,she,it based on sex of $r. |
| $k | - him,her,it based on sex of $i. |
| $m | - him,her,it based on sex of $n. |
| $M | - him,her,it based on sex of $t. |
| $K | - him,her,it based on sex of $r. |
| $l | - his,hers,its based on sex of $i. |
| $s | - his,hers,its based on sex of $n. |
| $S | - his,hers,its based on sex of $t. |
| $L | - his,hers,its based on sex of $r. |
| $o | - the first of the names of the primary object (i.e A drops B) |
| $O | - the short description of the primary object |
| $p | - the first of the names of the secondary object (i.e A puts B in C) |
| $P | - the short description of the secondary object |
| Variable | Argument | Meaning |
| ||
| status | if status $1 3 | - is the PC's status == 3 |
| pc_str | if pc_str $n >= 14 | - is the PC's strength >= 14 |
| pc_int | if pc_int $n <= 14 | - is the PC's intelligence <= 14 |
| pc_wis | if pc_wis $n == 14 | - is the PC's wisdom 14 |
| pc_dex | if pc_dex $n > 14 | - is the PC's dexterity > 14 |
| pc_con | if pc_con $n < 14 | - is the PC's constitution < 14 |
| pc_permstr | if pc_permstr $n >= 14 | - is the PC's PERM strength >= 14 |
| pc_permint | if pc_permint $n <= 14 | - is the PC's PERM intelligence <= 14 |
| pc_permwis | if pc_permwis $n == 14 | - is the PC's PERM wisdom 14 |
| pc_permdex | if pc_permdex $n > 14 | - is the PC's PERM dexterity > 14 |
| pc_permcon | if pc_permcon $n < 14 | - is the PC's PERM constitution < 14 |
| pc_hours | if pc_hours $n >= 10 | - if the PC has 10 or more hours played |
| pc_weight | if pc_weight $n < 250 | - PC Weight Check, standard operators |
| pc_clanlevel | if pc_clanlevel >= 8 | - Is PC's clan level over 8? |
| pc_bcopper | if pc_bcopper $n < 250 | - PC Bank Copper check |
| pc_bgold | if pc_bgold $n > 250 | - PC Bank Gold check |
| pc_bsilver | if pc_bsilver $n < 250 | - PC Bank Silver check |
| pc_bsteel | if pc_bsteel $n > 250 | - PC Bank Steel check |
| pc_bplatinum | if pc_bplatinum $n < 2 | - PC Bank Platinum check |
| pc_subclan | if pc_subclan1 $n subclan1 | - Is PC in subclan1? (see subclan list in helpfile) |
| pc_subclan2 | if pc_subclan2 $n subclan2 | - Is PC in subclan2? (see subclan list in helpfile) |
| pc_ispk | if pc_ispk $n | - Is $n (PC's only) a player killer? |
| rand | if rand 30 | - if random number < 30 |
| Subclans: | ||
| dagreen | if dagreen $n | - Dragonarmy and in Green (main or second) |
| dared | if dared $n | - Dragonarmy and in Red (main or second) |
| dablack | if dablack $n | - Dragonarmy and in Black (main or second) |
| dablue | if dablue $n | - Dragonarmy and in Blue (main or second) |
| dawhite | if dawhite $n | - Dragonarmy and in White (main or second) |
| orlouge | if orlouge $n | - Mariner AND Orlouge (main or subclans) |
| bilson | if bilson $n | - Mariner and in Bilson (main or second) |
| clwhite | if clwhite $n | - Conclave AND White (main or subclans) |
| clblack | if clblack $n | - Conclave AND Black (main or subclans) |
| clred | if clred $n | - Conclave AND Red (main or subclans) |
| hodark | if hodark $n | - Holy Order AND Dark (main or sub) |
| hobal | if hobal $n | - Holy Order AND Balance (main or sub) |
| holight | if holight $n | - Holy Order AND Light (main or sub) |
| rose | if rose $n | - Solamnic Rose |
| crown | if crown $n | - Solamnic Crown |
| sword | if sword $n | - Solamnic Sword |
| isnpc | if isnpc $n | - is $n a mobile |
| ispc | if ispc $n | - is $n a pc |
| isgood | if isgood $n | - is $n good |
| isevil | if isevil $n | - is $n evil |
| isneutral | if isneutral $n | - is $n neutral |
| isimmort | if isimmort $n | - is $n immortal |
| ischarm | if ischarm $n | - is $n charmed |
| isfollow | if isfollow $n | - is $n following, or being escorted |
| mobhere | if mobhere fido if mobhere 1233 | - is there a mob name 'fido' here - is there mob vnum 1233 here |
| objhere | if objhere bottle if objhere 1233 | - is there a object named 'bottle' here - is there obj vnum 1233 here |
| people | if people > 2 | - is there over 2 character in room |
| players | if players > 1 | - does room contain > 1 PCs |
| mobs | if mobs > 2 | - does room contain > 2 mobiles |
| mobexists | if mobexists fido | - is there a fido somewhere |
| objexists | if objexists sword | - is there a sword somewhere |
| clones | if clones > 3 | - are there > 3 mobs of same vnum here |
| order | if order == 0 | - is mob the first in room |
| hour | if hour >= 8 | - is the time after or equal to 8 o'clock |
| isactive | if isactive $n | - is $n's position != SLEEPING |
| pos | if pos $n standing | - is $n standing |
| language | if language $n human | - is $n's language human? |
| isdelay | if isdelay $i | - does $i have mobprog pending |
| isvisible | if isvisible $n | - can mob see $n |
| hastarget | if hastarget $i | - does $i have a valid target |
| istarget | if istarget $n | - is $n mob's target |
| exists | if exists $q | - does $n exist somewhere |
| affected | if affected $n blind | - is $n affected by blind |
| act | if act $i sentinel | - is $i flagged sentinel |
| off | if off $i berserk | - is $i flagged berserk |
| imm | if imm $i fire | - is $i immune to fire |
| carries | if carries $n sword if carries $n 1233 | - does $n have a 'sword' - does $n have obj vnum 1233 |
| wears | if wears $n lantern if wears $n 1233 | - is $n wearing a 'lantern' - is $n wearing obj vnum 1233 |
| has | if has $n weapon | - does $n have obj of type weapon |
| uses | if uses $n armor | - is $n wearing obj of type armor |
| name | if name $n puff | - is $n's name 'puff' |
| clan | if clan $n 'whatever' | - does $n belong to clan 'whatever' |
| race | if race $n dragon | - is $n of 'dragon' race |
| class | if class $n thief | - is $n a thief (mage, cleric, warrior etc) |
| objtype | if objtype $p scroll | - is $p a scroll |
| vnum | if vnum $i == 1233 | - virtual number check |
| hpcnt | if hpcnt $i > 30 | - if hit points are below 30% |
| room | if room $i == 1233 | - room virtual number |
| sex | if sex $i == 0 | - sex check |
| level | if level $n < 5 | - level check |
| align | if align $n < -1000 | - alignment check |
| money | if money $n | - does $n have X money? |
| objval0 | if objval0 > 1000 | - object value[] checks 0..4 |
| objval1 | if objval1 >= 3 | |
| objval2 | if objval2 != 6 | |
| objval3 | if objval3 > 5 | |
| objval4 | if objval4 < 124 | |
| grpsize | if grpsize $n > 6 | - group size check |
STATUS if_check: (Ansalon via Tyche)
MOB STATUS [int]
STATUS lets you check mobiles different states, this is
simply an integar you attach to them, and can check on them.
-=====-
Syntax:
if STATUS $i == 0
say My status is 0, going to 1
MOB STATUS 1
end
endif
if STATUS $i == 1
say My STATUS is 1, going to 2
MOB STATUS 2
end
endif
if STATUS $i == 2
say My STATUS is 2, going to 0
MOB STATUS 0
end
endif
end
PC_STR if_check: (Ansalon: not stock mprog code)
This check is a value comparison. Is the Strength of the player >=< the
argument.
-=====-
Syntax:
if PC_STR $n >= 18
say You are quite buff $N!
else
say Better hit the weights $N.
endif
PC_INT if_check: Current Stats Check
PC_WIS if_check:
PC_DEX if_check:
PC_CON if_check:
PC_STR if_check:
This check is a value comparison. Is the Strength of the player >=< the
argument.
-=====-
Syntax:
if PC_PERMSTR $n >= 18
say You are naturally very strong $N!
else
say Better hit the weights $N.
endif
PC_PERMINT if_check: PERMANENT Stats Check
PC_PERMWIS if_check:
PC_PERMDEX if_check:
PC_PERMCON if_check:
PC_HOURS if_check:
This check is a value comparison. Is the Hours played of the player >=< the
argument.
-=====-
Syntax:
if PC_HOURS $n >= 200
say Holy crap $N! You've been playing for ages.
else
say Play a while $N, you might like the place.
endif
PC_BCOPPER if_check: How much of that coin in the bank?
PC_BGOLD if_check:
PC_BSILVER if_check:
PC_BSTEEL if_check:
PC_BPLAT if_check:
Syntax:
if PC_BGOLD $n >= 200
say Holy crap $N! You have over 200 gold in the bank!
else
say You don't have very much money in the bank $N.
endif
PC_WEIGHT if_check:
This check is a value comparison. Is the Weight check of the player >=< the
argument.
-=====-
Syntax:
if PC_WEIGHT $n >= 600
say Holy crap $N, you weigh over 600 pounds!
else
say You aren't too heavy yet $N.
endif
PC_CLANLEVEL if_check:
This check is a value comparison. Is the clanlevel check of the player >=< the
argument.
-=====-
Syntax:
if PC_CLANLEVEL $n >= 8
say You are a recruiter $N.
else
say You better go talk to the boss $N.
endif
PC_Subclan if_check:
This check looks to see which subclan a player is in, only on PC's.
Solamnic: Crown = subclan1 = 1
Sword = subclan1 = 2
Rose = subclan1 = 3
Conclave: White = subclan1 = 1
Red = subclan1 = 2
Black = subclan1 = 3
Dragonarmy GREEN = subclan1 = 1
WHITE = subclan1 = 2
BLACK = subclan1 = 3
BLUE = subclan1 = 4
RED = subclan1 = 5
Holy Order: Light = subclan1 = 1
Balance = subclan1 = 2
Dark = subclan1 = 3
Mariner: Orlouge = subclan1 = 1
Bilson = subclan1 = 2
Wildrunner: Windrider = subclan1 = 1
Rogue: No subclans
Use subclan1 for primary clan, subclan2 for secondary.
-=====-
Syntax:
(Hint: Check main clan first>
if clan $n Solamnic
if pc_subclan1 $n 3
or pc_subclan2 $n 3
room echoat $n You are welcomed into the room, as an unseen servant prepares a chair.
room echoaround $n $n is welcomed into the room, as an unseen servant prepares a chair.
else
room echo Only Rose Knights are permitted in here.
endif
else
room echo Only Solamnics are allowed within.
endif
NOTE: You can use either subclan1 or the subclan name for the argument.
PC_ISPK if_check:
This check is simple, is the player a player killer?
-=====-
Syntax:
if pc_ispk $n
say You are a player killer!!!
cringe $n
else
say Hmm, scared of a little battle $n?
endif
RAND if_check:
This check is a value comparison. Is the a random number >= the argument.
-=====-
Syntax:
if RAND 30
say Hey, I got 30 or under in my roll!
else
say I rolled over 30.
endif
Specific SUBCLAN if_check:
This check is simple, Is the victim a in a certain subclan?
This checks clan AND subclan, so dared is dragonarmy AND in red subclan.
-=====-
Syntax:
if dagreen $n
say You are Dragonarmy Green!
endif
if dared $n
say You are Dragonarmy Red!
endif
if dablack $n
say You are Dragonarmy Black!
endif
if dablue $n
say You are Dragonarmy Blue!
endif
if dawhite $n
say You are Dragonarmy White!
endif
if orlouge $n
say You are Mariner Orlouge!
endif
if bilson $n
say You are Mariner Bilson!
endif
if clwhite $n
say You are Conclave White!
endif
if clblack $n
say You are Conclave Black!
endif
if clred $n
say You are Conclave Red!
endif
if hodark $n
say You are Holy Order Dark!
endif
if hobal $n
say You are Holy Order Balance!
endif
if holight $n
say You are Holy Order Light!
endif
if rose $n
say You are Solamnic Rose!
endif
if crown $n
say You are Solamnic Crown!
endif
if sword $n
say You are Solamnic Sword!
endif
ISNPC if_check:
This check is simple, Is the victim a mob?
-=====-
Syntax:
if ISNPC $n
say Hey, you're a mob, go away.
else
say You're a player!
endif
ISPC if_check:
This check is simple, Is the victim a player character?
-=====-
Syntax:
if ISPC $n
say You're a player!
else
say Hey, you're a mob, go away.
endif
ISGOOD if_check:
This check is a value comparison, Is the victim good? (alignment number check)
-=====-
Syntax:
if ISGOOD $n
say You're a goody two-shoes, You're a goody two-shoes.
emote dances around
emote pokes you in the eye.
else
say You aren't a goody goody.
sniff
endif
ISEVIL if_check:
This check is a value comparison, Is the victim evil? (alignment number check)
-=====-
Syntax:
if ISEVIL $n
say You are Soooooo Evil $N!!
cower $n
else
say You aren't bad at all $N.
smile
endif
ISNEUTRAL if_check:
This check is a value comparison, Is the victim neutral? (alignment number
check)
-=====-
Syntax:
if ISNEUTRAL $n
say You are quite neutral $N.
else
say You must be good or evil $N.
emote looks at you with a suspicious sidelong glance.
endif
ISIMMORT if_check:
This check is a value comparison, Is the victim's level above hero? (102+)
-=====-
Syntax:
if ISIMMORT $n
say Hello there your godliness $N.
else
say You are a mortal!
say You will DIE $N!!!
mob kill $n
endif
NOTE: Very useful if you have a GRALL program and don't want immortals to
have it trigger. Or have a program to damage players, leaves imms alone.
ISCHARM if_check:
This check is simple, Is the victim charmed?
-=====-
Syntax:
if ISCHARMED $n
say Not thinking for yourself lately I see, who's your master $N?
else
say You have much free will $N.
endif
ISFOLLOW if_check:
This check is simple, Is the victim following someone here?
-=====-
Syntax:
if ISFOLLOW $n
nod $n
say You may pass, but don't come here unescorted $N.
else
say You don't belong here $N!!
mob transfer $N pole
endif
NOTE: This is useful for clans (escort), for prisons etc.
MOBHERE if_check:
This check is simple, Is a certain mob here?
-=====-
Syntax:
if MOBHERE tarantula
mob force tarantula mob kill $n
else
say Damn, if my spider was here, you'd be toast $N.
endif
NOTE: You can interchange the name with a vnum to be more specific.
OBJHERE if_check:
This check is simple, Is a certain object here?
-=====-
Syntax:
if OJBHERE table
sit table
else
say Damn, did you take my table $R.
endif
NOTE: You can interchange the name with a vnum to be more specific.
PEOPLE if_check:
This check is a value comparison, are there argument PC's + NPC's here?
-=====-
Syntax:
if PEOPLE >= 5
say Wow, we're getting full in here.
else
say The place seems pretty deserted doesn't it $N?
endif
NOTE: You can be more specific with MOBS or PLAYERS checks, to determine
numbers of PC's or NPC's.
PLAYERS if_check:
This check is a value comparison, are there argument players here?
-=====-
Syntax:
if PLAYERS >= 2
say Quite a few players here.
else
say You're the only player here $N.
endif
MOBS if_check:
This check is a value comparison, are there argument mobs here?
-=====-
Syntax:
if MOBS >= 2
say Quite a few mobs here $N.
say Why don't you kill some?
else
say Not very many mobs here $N.
endif
MOBEXISTS if_check:
This check is simple, is there a mob called/number argument in existance?
-=====-
Syntax:
if MOBEXISTS Julia
say You should go talk to Julia $N.
else
say Julia must not be around $N.
endif
OBJEXISTS if_check:
This check is simple, is there an object called/number argument in existance?
-=====-
Syntax:
if OBJEXISTS whitegold
say Sorry $N, you can't have one, someone already has a White Gold Ring.
else
say Oh sure, take my nice ring $N.
mob oload 1342134 0 none
give ring $n.
endif
CLONES if_check:
This check is a value comparison, are there argument of the same mob here?
-=====-
Syntax:
if clones >= 4
say More than four!
else
if clones == 3
say Exactly three, plus me!
else
if clones == 2
say Exactly two, plus me!
else
if clones == 1
say Just one clone of me!
else
if clones == 0
say Not just me!
else
say Just me!
endif
endif
endif
endif
endif
NOTE:
Clone can be used with the usual operators > < >= <= ==.
It checks for clones of itself, so if clones == 1, means
there is ONE mob JUST like it in the room, it's clone.
If clones can be used to check IN ROOM only.
It's useful for a guard loading more guards, but only
if there are only say less than 8 in the room.
ORDER if_check:
This check is a value comparison, is victim the argument in line?
-=====-
Syntax:
if ORDER $n >= 2
say Why don't you ask your master $N?
else
say Ahh, you are the boss $N.
endif
NOTE: This one is useful for letting the mob only listen to the first person
to come into the room, or to attack the person if they are second etc.
HOUR if_check:
This check is a value comparison, does the time >=< the argument?
-=====-
Syntax:
if HOUR >= 8
say Wow, it's past eight already.
else
say Sorry, I don't do squat until 8 am $N.
endif
NOTE: This check can be used to have the mob do certain things at certain
times, like closeup shop, sell certain items at certain times (via
mob oload etc). All sorts of uses.
ISACTIVE if_check:
This check is simple, is victim NOT sleeping?
-=====-
Syntax:
if ISACTIVE $i
say Hey, I'm awake already.
else
rest
stand
emote looks around with bleary eyes.
endif
NOTE: This check can be used to have the mob do certain things based on its
position, like wake if it's sleeping, or not attack if it has a grall etc.
LANGUAGE if_check:
This check is a value check, is victim's language the same as the argument?
-=====-
Syntax:
if language $i goblin
say I'm speaking goblin, you fool you can't understand me.
else
say I'm uh, not speaking goblin!
endif
NOTE: A good way to use this particular one is to check the target, then say
something else, this simulates subterfuge. Or have the target ONLY accept
the command in the language it wants!
IE:
If language $n silvanesti
say My greetings $n, that is the correct password.
MOB TRANS $n 1234
else
language silvantesti
say I only speak Silvanesti you uncouth heathen.
endif
POS if_check:
This check is a value check, is victim in the position argument?
-=====-
Syntax:
if POS $i fighting
say Hey, I'm kind of busy here $N, please come back later.
else
say Hey, I'm not fighting, wanna brawl $N?
endif
NOTE: This check can be used to have the mob do certain things based on its
position, or check others, like 'if pos $N fighting' say Calm down $N! etc.
Or if position $r sleeping, wake $r, say No sleeping $R!!
ISDELAY if_check:
This check is simple, does <actor> have a delay?
-=====-
Syntax:
if ISDELAY $i
say Sorry $N, I'm busy already.
else
mob remember $n
mob delay 20
endif
NOTE: This check is very useful for having mobs act out things via delay.
It keeps them from changing the delay, or starting it over before they
finish the first one. Also, other mobs can see if a certain mob is busy etc.
ISVISIBLE if_check:
This check is simple, is victim able to be seen by the mob?
-=====-
Syntax:
if ISVISIBLE $n
say I can seeeee you!
else
say Hey, who's there?
endif
NOTE: Useful for having mobs not try to do something with someone they can't see.
HASTARGET if_check:
This check is simple, does <actor> have a target? ($q)
-=====-
Syntax:
if HASTARGET $i
say Hey, have you seen $Q $N?
else
say Hey, I'll remember you $N!
mob remember $n
endif
NOTE: This one is great for mobs checking first to see if they are already
after someone etc.
ISTARGET if_check:
This check is simple, is victim the target of $i?
-=====-
Syntax:
if ISTARGET $n
say Hey, just the man I've been looking for $Q!
mob kill $Q
mob forget
else
say You're not who I'm looking for $N, I'm after $Q.
endif
NOTE: This one works with HASTARGET well to determine who the mob is after etc.
EXISTS if_check:
This check is simple, does $q exist?
-=====-
Syntax:
if EXISTS $q
mob at $q mob echoat $q Time to come home $Q.
mob at $q mob echoaround $q $I comes to take $Q home for dinner.
mob at $q mob transfer $q 12151
else
say My victim has left the game.
mob forget.
endif
NOTE: Useful for having mobs not error when looking for a target that has
quit the game. You can also use it with a name of obj/mob etc.
AFFECTED if_check:
This check is a value check, is victim affected by argument?
-=====-
Syntax:
if AFFECTED $n fly
mob echo You float across the water.
else
mob echo You begin to drown in the pool!
mob damage $n 100 200 lethal
endif
NOTE: Can also be used to have the mob see if it is affected by spells etc.
IE. if AFFECTED $i haste
break
else
eat pill
endif
ACT if_check:
This check is a check against the victim for how they act.
-=====-
Syntax:
if ACT $i warrior
flex
say I'm a tough warrior.
mob kill $n
else
say I'm much to wimpy to fight you $N.
endif
NOTE: This is useful if you are using the same mprog on a few mobs and want
them to react differently depending on how thier 'act's are set.
OFF if_check:
This check is a check against the victim for what offensive behaviors
are set for them.
-=====-
Syntax:
if OFF $i dirtkick
emote looks at the ground.
dirt $n
else
say You know, I'd kick dirt on you if I could.
grumble
endif
NOTE: This is useful if you are using the same mprog on a few mobs and want
them to react differently while fighting depending on how thier 'OFF's are
set.
IMM if_check:
This check is a check against the victim what Immunities they have.
-=====-
Syntax:
if IMM $n magic
say Damnit, my magic can't harm you $N.
emote slashes at you with a dagger instead.
else
say Ha ha!
mob cast fireball $n
endif
NOTE: This works well for mobs fighting to not make the mistake of trying
damage mobs/pc's with things those mobs/PC's are immune to. IE, IMM cold
so the mob loads a different weapon that isn't flagged cold, etc.
CARRIES if_check:
This check looks to see if the victim carries or wears the argument (vnum or
name)
-=====-
Syntax:
if CARRIES $n sword
say That's a nice sword you have there $N.
else
say You should go buy a sword.
endif
NOTE: This check only checks to see if they are equiped with or have the
item in thier inventory. If it's inside a container, it will not
trigger (will do the else statement).
WEARS if_check:
This check looks to see if the victim wears(has equipped) the argument (vnum or
name)
-=====-
Syntax:
if WEARS $n holy symbol
bow $n
say Welcome to our humble sanctuary $N.
else
say You shouldn't be here $N.
mob force $N south
endif
NOTE: This check only checks to see if they are equiped the item. If it's inside
a container, or just in inventory, it will not trigger (will do the else
statement).
HAS if_check:
This check looks to see if the victim carries,wears, or has the argument (vnum
or name)
-=====-
Syntax:
if HAS $n dagger
if WEARS $n dagger
say That dagger looks real sharp $N.
else
say Your dagger would be better used in your hand $N.
mob force $n wear dagger
endif
else
say You should go buy a dagger $N.
endif
NOTE: This check checks to see if they are equiped with, have the
item in thier inventory, or inside a container. Just flat out, do
they 'have' one?
USES if_check:
This check looks to see if the victim is wearing the TYPE of argument.
-=====-
Syntax:
if USES $n light
say Not so dark is it $N?
else
say Nyyaaa, it's dark and you can't see me!
endif
NOTE: This check checks to see if they are EQUIPPED with a certain TYPE of
object. Rather than the name or vnum of it, it looks for object type.
NAME if_check:
This check checks the name of an object/victim.
-=====-
Syntax:
if NAME $o pie
say Yum, what a tasty pie!
eat pie
else
say Hey, this is an $O, I wanted a pie!
endif
NOTE: This check looks at the name of a victim or object, useful for personal
rooms with a NAME check to make sure it's the right person going in.
Or an exact object they are looking for etc.
CLAN if_check:
This check checks the CLAN of the victim.
-=====-
Syntax:
if CLAN $n kot
salute $n
say Welcome home $N.
else
say Hey, you aren't a Knight of Takhisis!!
scream
mob kill $n
endif
NOTE: This check looks at the clan affiliation of the victim.
RACE if_check:
This check checks the RACE of the victim.
-=====-
Syntax:
if RACE $n gnome
grumble
say Wherehaveyoubeen$N?
else
say You aren't a gnome, want to see the flinger?
endif
NOTE: This check looks at the race of the victim.
CLASS if_check:
This check is simple. Is the player class of $N = the argument.
-=====-
Syntax:
if CLASS $n thief
say You are a thief, come on in and take my stuff!
else
say Whew, you aren't a thief, you had me worried $N.
endif
NOTE: Useful for training halls etc.
OBJTYPE if_check:
This check checks the type of object of the victim.
-=====-
Syntax:
if OBJTYPE $o food
say Thanks, I was very hungry!
eat $o
say Mmmm, that $O was delicious $N!
else
say This isn't food!
drop $o
emote hops around rubbing $k tummy.
endif
VNUM if_check:
This check checks the virtual number of the victim.
-=====-
Syntax:
if VNUM $i 12345
say I am a strong guard.
flex
else
say I am a ninny squire!
say I wish I was a guard.
endif
NOTE: This is useful if you wish to make a complex mprog for a few mobs, then
have it so the mob's own vnum determines what it does based on the prog.
HPCNT if_check:
This check checks the type of hit point percentage of the victim.
-=====-
Syntax:
if HPCNT $i >= 30
say Damn $N, you're kicking my ass!
else
say I'm not quite dead!
endif
NOTE: Useful for making mobs flee, or bring in reinforcements. Combine with
a if POS $n/$i fighting, for an effective program.
ROOM if_check:
This check checks the virtual number of the room the victim is in.
-=====-
Syntax:
if ROOM $i == 12345
say I am standing in the East Wing.
push $n west
else
if ROOM $i == 12346
say I am standing in the West Wing.
push $n east
else
say I'm not in my room.
sniff
endif
endif
NOTE: This is useful if you wish to make a complex mprog for a few rooms, then
have it so the mob's room determines what it does based on the prog.
SEX if_check:
This check checks the sex of the victim.
-=====-
Syntax: (1 is male, 2 is female, 0 is 'IT')
if SEX $n == 1
say Hey there big boy.
else
if SEX $n == 2
say Hey there hot mamma.
else
say Oh my god!
say You're an IT!!!!
endif
endif
NOTE: Sex check, works well for different actions based upon sex of the PC.
LEVEL if_check:
This check checks the level or level range of the victim.
-=====-
Syntax:
if LEVEL $n >= 5
say You're sure getting up there in levels $N.
else
say You need to go level $N!
endif
ALIGN if_check:
This is a value comparison. The program checks the alignment number of the
victim.
-=====-
Syntax:
if ALIGN $n >= 0
say You aren't so bad.
else
say You aren't so good.
endif
NOTE: This check is more specific than the ISGOOD/EVIL/NEUTRAL check, allowing
you to select exact numbers other than -333 0 and 333.
MONEY if_check:
This is a value comparison. The program checks the combined money of the victim.
-=====-
Syntax:
if MONEY $i >= 300
say I'm pretty rich
else
say Dang, I dont have much money.
emote Opens a safe.
mob oload 12314 0 room
get coins
say Now I'm rich!
endif
NOTE: This check can be used to see if players have enough cash to pay for
something, before they attempt it. Or give the mobs more cash etc.
OBJVAL0-4 if_check:
This is a value comparison. The program checks the value of the object.
-=====-
Syntax:
if OBJTYPE $o food
if OBJVAL3 $o > 0
say Are you trying to poison me?
mob kill $n
else
say Thanks $n, I was famished!
eat $o
endif
else
say I really could use some food.
give $o $n
endif
GRPSIZE if_check:
This is a value comparison. The program checks the group size of the victim.
-=====-
Syntax:
if GRPSIZE $n >= 7
say Hello there your lordship.
else
say Hehe, you don't look so tough.
mob kill $n
endif
NOTE: This check can be used to have the mob estimate a group size, either
it's own group (and load more mobs), or the victims group, and fight
(or not fight, or load more mobs ;p).
| == | is equal to |
| != | is NOT equal to |
| > | is greater than |
| < | is less than |
| >= | is greater than or equal to |
| <= | is less than or equal to |
The provided list of if_checks and their arguments are below. They
should all be fairly obvious in what they do, but some of the more obtuse
deserve a slight explanation. Any '==' operator can be replaced with any of
the available ones described above. The argument $* refers to any of the
variables which make sense for that if_check (i.e. for an if_check which is
referencing a person the only valid variables would be $i, $n, $t, $r or $q)
A value type of string is a sequence of characters. It does not need to be
included in quotes or anything like that (i.e. if name $n fido )
There are five types of if checks:
Type 1: Keyword/value Explanation
rand num - Is random percentage less than or equal to num
mobhere vnum - Is a NPC with this vnum in the room
mobhere name - Is a NPC with this name in the room
objhere vnum - Is an object with this vnum in the room
objhere name - Is an object with this name in the room
mobexists name - Does NPC 'name' exist somewhere in the world
objexists name - Does object 'name' exist somewhere in the world
Type 2: Keyword/compare/value Explanation
people == integer - Is the number of people in the room equal to integer
players == integer - Is the number of PCs in the room equal to integer
mobs == integer - Is the number of NPCs in the room equal to integer
clones == integer - Is the number of NPCs in the room with the same
vnum as the NPC who activated the program equal
to integer
order == integer - Is the order (of several similar NPCs) of the NPC
who activated the trigger equal to integer
hour == integer - Is the hour (game time) equal to integer
Type 3: Keyword/actor Explanation
isnpc $* - Is $* an NPC
ispc $* - Is $* a PC
isgood $* - Does $* have a good alignment
isneutral $* - Does $* have a neutral alignment
isevil $* - Does $* have an evil alignment
isimmort $* - Is $* an immortal (level of $* > LEVEL_HERO)
ischarm $* - Is $* affected by charm
isfollow $* - Is $* a follower with their master in the room
isactive $* - Is $*'s position > POS_SLEEPING
isdelay $* - Does $* have a delayed MOB PROGRAM pending
isvisible $* - Is $* visible to NPC who activated the program
hastarget $* - Does $* have a MOB PROGRAM target in the room
istarget $* - Is $* the target of NPC who activated the program
Type 4: Keyword/actor/value Explanation
affected $* 'affect' - Is $* affected by 'affect'
act $* 'act' - Is $*'s ACT bit 'act' set
off $* 'off' - Is $*'s OFF bit 'off' set
imm $* 'imm' - Is $*'s IMM bit 'imm' set
carries $* 'name' - Is $* carrying object 'name'
wears $* 'name' - Is $* wearing object 'name'
has $* 'type' - Does $* have object of item_type 'type'
uses $* 'type' - Is $* wearing object of item_type 'type'
name $* 'name' - Is $*'s name 'name'
pos $* 'position' - Is $*'s position 'position' (sleeping etc.)
clan $* 'name' - Does $* belong to clan 'name'
race $* 'name' - Is $* of race 'name'
class $* 'name' - Is $*'s class 'name'
objtype $* 'type' - Is $*'s item_type 'type'
Type 5: Keyword, actor, comparison and value
vnum $* == integer - Is $*'s virtual number equal to integer
hpcnt $* == integer - Is $*'s hitpoint percentage equal to integer
room $* == integer - Is vnum of the room $* is in equal to integer
sex $* == integer - Is $*'s sex equal to integer
level $* == integer - Is $*'s level equal to integer
align $* == integer - Is $*'s alignment equal to integer
money $* == integer - Does $* have money (in gold) equal to integer
objval# $* == integer - Is $*->value[#] equal to integer (# from 0-4)
NOTE:
The original MERC 2.2 MOBprograms used parenthesis '(' and ')'
around variables. In this version, they are NOT allowed. Also,
parameters MUST BE separated with spaces (Correct syntax is: if level $n < 10).
MLOAD (mobile) - Lets the mobile load another mobile.
OLOAD (obj vnum) (level) (location) - Lets the mobile load an object
2ND ARGUMENT
# - the level to load the object at
Use 0 if you wish to continue building.
3RD ARGUMENT
None - inventory
R - in room (can also use Room)
W - on mob (must be hold/wearable)
KILL (victim) - Lets the mobile kill any player or mobile
without murder
ASSIST (victim) - Lets the mobile assist another mob or player
MPDUMP 1234 - Displays the source code of a given MOB PROGRAM
ECHO (text_string) - Prints the message to the room at large
ECHOAT (victim) [string] - Prints the message to only the victim
ECHOAROUND (victim) [string] - Prints the message to everyone in the room other
VECHO (room vnum> [string] - Echo a string at a specific room
MVECHO (vnum vnum> [string] - Echo a string at a specific RANGE of rooms
GECHO (text_string) - Prints the argument to all active players
ZECHO (text_string) - Prints the argument to all players in the
same area as the mob
ASOUND (text_string) - Prints the argument to all the rooms around the mobile
than the mob and victim
PURGE (target) - Lets the mobile purge all objects and other
npcs in the room, or purge a specified object
or mob in the room. The mobile can
purge itself, but it must be the last command.
GOTO (dest) - Lets the mobile goto any location it wishes
that is not private.
AT (location) [commands] - Lets the mobile do a command at another location.
TRANSFER (target|'all') [location]- Lets the mobile transfer people. The 'all'
argument transfers everyone in the current
room to the specified location
(room vnum or mobile name)
SLIP (target|'all') [location]- Lets the mobile slip people. The 'all'
argument transfers everyone in the current
room to the specified location
(room vnum or mobile name)
NOTE: This is a transfer, but there is no
'look' so the PC won't know it happened.
GRTRANSFER (victim) [location] - Lets the mobile transfer all chars in same group
as the victim.
OTRANSFER (item name) [location] - Lets the mobile to transfer an object. The object
must be in the same room with the mobile.
REMOVE (victim) [object vnum|'all']- Lets the mobile to strip an object or all objects
from the victim. Useful for removing e.g.
quest objects from a character.
JUNK (object) - Lets the mobile destroy an object in
its inventory
- it can also destroy a worn object and
it can destroy items using all.xxxxx
or just plain all of them
FORCE (victim) [commands] - Lets the mobile force someone to do something.
Must be mortal level and the all argument only
affects those in the room with the mobile.
GFORCE (victim) [commands] - Lets the mobile force a group something. Must be
mortal level.
VFORCE 1234 [commands] - Forces all mobiles of certain vnum to do something
CAST (spell) [target] - Lets the mobile cast spells --
Beware: this does only crude checking on the target
validity and does not account for mana etc., so
you should do all the necessary checking in your
mob program before issuing this cmd!
DAMAGE (victim) [min] [max] (kill)- Lets mob cause unconditional damage to someone.
Nasty, use with caution.
Also, this is silent, you must show your own
damage message... If kill parameter is omitted,
this command is "safe" and will not kill the victim.
REMEMBER (victim) - Lets the mobile to remember a target. The target can
be referred to with $q and $Q codes in MOBprograms.
See also "mob forget".
FORGET (victim) - Reverse of "mob remember".
DELAY (pulses) - Sets a delay for MOB PROGRAM execution. When the
delay time expires, the mobile is checked for a
Mob program with DELAY trigger, and if one is
found, it is executed. Delay is counted in PULSE_MOBILE
CANCEL - Reverse of "mob delay", deactivates the timer.
CALL [vnum] [victim|'null'] [object1|'null'] [object2|'null']
- Lets the mobile to call another MOB PROGRAM withing
a MOB PROGRAM.
This is a crude way to implement subroutines/
functions. Beware of nested loops and unwanted
triggerings... Stack usage might be a problem.
Characters and objects referred to must be in
the same room with the mobile.
FLEE - Forces the mobile to flee.
STATUS - An integar the mob can set/change on itself.
PORTALTO (vnum to) (portal used)- This command let's a mob create a portal
between the room it's in, and
the room you specify (if you
specify a portal then it uses
THAT one, so you can use a
specific gangplank, door etc).
GOTORESET No argument used, this will take the mob back to
the room that it loaded in, it's reset room.
MOBcommands are special commands that allow mobiles to perform
immortal-like actions within a MOB PROGRAM (transferring players
or loading items, for example). Most MOBcommands them are wiz
commands which have been changed to allow for mobiles to perform
the commands. In this version of MOBprograms, players have been
prevented from using these commands by adding a separate
interpreter for MOBcommands. This also speeds up (in most cases)
MOB PROGRAM execution when MOBcommands are used. All MOBcommands
are preceded with the word 'MOB' on the command line.
MOB STATUS [int]
NOTE:
STATUS lets you put mobiles in different states, this is
simply an integar you attach to them, and can check on them.
Syntax Example:
if STATUS $i == 0
say My status is 0, going to 1
MOB STATUS 1
end
endif
if STATUS $i == 1
say My STATUS is 1, going to 2
MOB STATUS 2
end
endif
if STATUS $i == 2
say My STATUS is 2, going to 0
MOB STATUS 0
end
endif
end
Note: (the 'end' in each check, good thing, or the mob will keep going)
This command can make the mob MUCH more intelligent to react with.
Many thanks to Tyche.
MOB ASOUND [string]
MOB ZECHO [string]
MOB GECHO [string]
NOTE:
ASOUND prints the text string to the rooms around the mobile in
the same manner as a death cry. This is really useful for
powerful aggressives and is also nice for wandering minstrels or
mobiles like that in concept. (Or certain gnomish contraptions ;0)
ZECHO prints the string to all players in the same area with the
mobile. Short for Zone Echo.
GECHO prints the string to all players in the game. Short for Global Echo.
MOB ECHO [string]
MOB ECHOAT [victim] [string]
MOB ECHOAROUND [victim] [string]
Note:
ECHO displays the string to everyone in the room.
ECHOAT displays the string to the victim only.
ECHOAROUND displays the string to everyone except the victim.
The three options let you tailor the message to goto victims or
to do things sneaky like having a merchant do: mob at guard mob
echoat guard rescue_please This coupled with a guard act trigger
on rescue_please to: mob goto $n mob echo $I has arrived. It is
an affective way of quickly bringing guards to the scene of an
attack. (Note that the merchant has to be the only one of its
kind in the game or have a unique name, otherwise the guard
might go to different mobile...).
MOB MLOAD [vnum]
MOB OLOAD [vnum] {'room'|'wear'}
(without second argument, loads in inventory)
Note:
MLOAD creates a mobile and places it in the same room with the
mobile. OLOAD loads the object into the inventory of the mobile.
Even if the item is non-takable, the mobile will receive it in
the inventory. This lets a mobile distribute a quest item or
load a key or something. The optional 3rd parameter can be
specified; 'room' means to load the object to the room, 'wear'
means to force the mobile to wear the object loaded (useful for
equipping mobiles on the fly).
MOB KILL [victim]
Note:
Lets a mobile kill a player without having to murder. Many
MOBprograms end up with mob kill $n commands floating around. It
works on both mobiles and players.
MOB FLEE
Note:
Causes a mobile to unconditionally flee from combat. Can be used
for example with the hit point percentage trigger to simulate
"wimpy" behavior.
MOB REMOVE [victim] [vnum|'all']
Note:
Lets the mobile to strip an object of given vnum from the
victim. Objects removed are destroyed. If the vnum is replaced
with "all", the whole inventory of the victim is destroyed. This
command is probably most useful for extracting quest items from
a player after a quest has been completed.
MOB JUNK [object]
Note:
Destroys the object referred to in the mobile's inventory. It
prints no message to the world and you can do things like junk
all.bread or junk all. This is nice for having janitor mobiles
clean out their inventory if they are carrying too much (have a
MOB PROGRAM trigger on the 'full inventory')
MOB PURGE [argument]
Note:
Destroys the argument from the room of the mobile. Without an
argument the result is the cleansing of all NPC's and items from
the room with the exception of the mobile itself. However,
mppurge $i will indeed purge the mobile, but it MUST be the last
command the mobile tries to do, otherwise the mud cant reference
the acting mobile trying to do the commands and bad things
happen.
MOB AT [location] [command]
Note:
Performs the command at the designated location. Very useful for
doing magic slight of hand tricks that leave players dumbfounded..
such as metamorphing mobiles, or guard summoning, or corpse
vanishing.
MOB GOTO [location]
Note:
Moves the mobile to the room or mobile or object requested. It
makes no message of its departure or of its entrance, so these
must be supplied with echo commands if they are desired.
MOB TRANSFER [victim/'all'] [location]
MOB GTRANSFER [victim] [location]
MOB OTRANSFER [object] [location]
Note:
Sends the victim to the destination or to the room of the mobile
as a default. if the victim is "all" then all the characters in
the room of the mobile are transferred to the destination. Good
for starting quests or things like that. There is no message
given to the player that it has been transferred and the player
doesn't do a look at the new room unless the mob forces them to.
Gtransfer works like transfer, except that the group the victim
belongs to is transferred with the victim. Otransfer
transfers an object in the room.
MOB FORCE [victim/'all'] [command]
MOB GFORCE [victim] [command]
MOB VFORCE [vnum] [command] ***** Didn't seem to work on Ansalon
Note:
Forces the victim to do the designated command. The victim is
not told that they are forced, they just do the command so
usually some MOB ECHO message is nice. You can force players to
remove belongings and give them to you, etc. The player sees
the normal command messages (such as removing the item and
giving it away in the above example) Again, if the victim is
"all" then everyone in the mobiles room does the command. Gforce
works like force except that it affects the group the victim
belongs to.
Vforce affects all mobiles with given vnum in the game world.
This is useful for, for example, purging certain type of NPCs
from the game (by forcing them to purge themselves).
MOB CAST [spell] [victim]
Note:
Lets the mobile to cast spells. Beware, this does only crude
validity checking and does not use up any mana. All spells are
available regardless of the race or other abilities of the
mobile. Casting the spell occurs silently, but spell effects are
displayed normally.
MOB DAMAGE [victim/'all'] [min] [max] {lethal}
Note:
Causes unconditional damage to the victim. Specifying "all" as
victim causes damage to all characters in the room except the
mobile. Min and max parameters define the minimum and maximum
amounts of damage caused. By default, the damage is non-lethal,
but by supplying the optional 'lethal' parameter, the damage can
kill the victim. This command is silent, you must echo all
messages yourself in the program. Useful for implementing
special attacks for mobiles.
MOB DELAY
MOB CANCEL
Note:
MOB DELAY sets the time in PULSE_MOBILE after which the mobile's
delay trigger is activated. If the mobile has a program defined
for delay trigger, the program is executed when the timer expires.
MOB CANCEL resets the delay timer.
MOB REMEMBER [victim]
MOB FORGET
Note:
This command enables the mobile to remember a player for future
reference in a MOB PROGRAM. The player can subsequently be
referred as '$q' in programs activated by the mobile. MOB FORGET
clears the target. Note that if the first time the mobile runs a
program, $q is automatically set to the player who triggered the
event. Most commonly this command is used in delayed programs,
where the mobile has to remember the player who triggered the
original event, for example to continue conversation.
MOB CALL [vnum] {victim} {target1} {target2}
Note:
This command lets you call MOBprograms from within a running
one, i.e. to call a MOB PROGRAM subroutine. The first parameter
is the vnum of the program to execute, the second is the
victim's name (for example $n), and the third and fourth are
optional object names. All other parameters except vnum can be
replaced with word 'null' indicating ignored parameter.
MOBprograms can be called recursively, but as a safety measure,
parser allows only 5 recursions (unless altered).
MOB PORTALTO [vnum][portal vnum]
Note:
This command lets mobs link areas with portals, if you don't
specify a portal (or use #25) it will vape in 10 ticks.
Example: We have a new gangplank portal named gangplank trsgp
(Pick a UNIQUE name if you want the mob to be able to find/purge old ones)
if objexists trsgp
mob at trsgp mob purge trsgp
endif
if objexists trsgp
mob at trsgp mob purge trsgp
endif
say Thanks, we're just arriving at the docks of Caergoth now!
mob portalto 16200 13610
mob echo A sailor pushes a gangplank off the stern onto the docks at Caergoth.
mob vecho 16200 A sailor ties off the Percheron and pushes a gangplank to the dock.
mob junk ticket
Adding the Mobprog to the MOB
Commands within Medit (while editing a mob, AFTER mprog created)
addmprog [vnum] [trigger] [phrase]
Example: (with a mob being edited)(medit)
addmprog 13456 greet 80 - This adds mprog 13456 to the mobile,
which greets pc's when they enter
80% of the time.
delmprog 0 (or 1,2,3 etc) - removes an mprog from a mob.
NOTE:
[vnum] The vnum of the mob program (mpedit)
[trigger] List of valid triggers and explanations above
[phrase] A single word, or a phrase within quotes
(example: "looks at you" or "yes" etc)
Or a percentile (ie '80' happens 80% of the time)